Importar ordenes de compra desde excel via DI API

Bueno, continuando con la programacion en vba, hoy quiero mostrarles como se puede importar un documento (en este caso orden de compra) a SAP usando una hoja de excel y unas pocas lineas de codigo.

Para ver los pasos previos (necesarios para que funcione el codigo), deben mirar el primer post;

Programar una macro para importar desde excel usando la DI API

Vamos a comenzar abriendo MS Excel y a llenar los datos como se muestra en esta imagen (los titulos los pueden colocar a su gusto). El boton no es necesario que lo agreguen aun.

Una vez colocado esos datos (obviamente con los codigos de su compañia), vamos a la ventana de macros y pegamos el siguiente codigo.

Public oCompany As SAPbobsCOM.Company

Public Sub ConnSAP()

        Dim lRetCode, ErrorCode As Long
        Dim ErrorMessage As String
        
        Set oCompany = New SAPbobsCOM.Company
        
        oCompany.DbServerType = SAPbobsCOM.BoDataServerTypes.dst_MSSQL2008
        oCompany.DbUserName = "sa"
        oCompany.DbPassword = "SAP*****"
        oCompany.Server = "sap9"
        oCompany.CompanyDB = "SBO_DemoCL"
        oCompany.UserName = "manager"
        oCompany.Password = "********"
        oCompany.UseTrusted = False
        oCompany.Language = ln_Spanish_La
        
        lRetCode = oCompany.Connect()
        If lRetCode <> 0 Then
            MsgBox (oCompany.GetLastErrorDescription())
        Else
            Imp_OC
        End If
End Sub

Public Sub Imp_OC()
        
        Dim Retval As Long
        Dim vDoc As SAPbobsCOM.Documents
        
        Set vDoc = oCompany.GetBusinessObject(oPurchaseOrders)
        
        RowC = 2
        RowD = 5
        
        If ActiveSheet.Cells(RowC, 1) <> "" Then
        
            vDoc.CardCode = ActiveSheet.Cells(RowC, 1)
            vDoc.CardName = ActiveSheet.Cells(RowC, 2)
            vDoc.DocDate = ActiveSheet.Cells(RowC, 3)
            vDoc.DocDueDate = ActiveSheet.Cells(RowC, 4)
            
            vDoc.Lines.ItemCode = ActiveSheet.Cells(RowD, 1)
            vDoc.Lines.Quantity = ActiveSheet.Cells(RowD, 2)
            vDoc.Lines.Price = ActiveSheet.Cells(RowD, 3)
            vDoc.Lines.WarehouseCode = ActiveSheet.Cells(RowD, 4)
            vDoc.Lines.TaxCode = ActiveSheet.Cells(RowD, 5)
            
            RowD = RowD + 1

            Do While ActiveSheet.Cells(RowD, 1) <> ""
            
                vDoc.Lines.Add
                                
                vDoc.Lines.ItemCode = ActiveSheet.Cells(RowD, 1)
                vDoc.Lines.Quantity = ActiveSheet.Cells(RowD, 2)
                vDoc.Lines.Price = ActiveSheet.Cells(RowD, 3)
                vDoc.Lines.WarehouseCode = ActiveSheet.Cells(RowD, 4)
                vDoc.Lines.TaxCode = ActiveSheet.Cells(RowD, 5)
            
                RowD = RowD + 1
                
            Loop
            
            Retval = vDoc.Add
            If Retval <> 0 Then
                MsgBox (oCompany.GetLastErrorDescription())
            Else
                MsgBox ("OK")
            End If
        Else
            MsgBox ("Nada que cargar")
        End If
        
        oCompany.Disconnect
End Sub

Acto seguido, volvemos a excel y agregamos un boton de formulario en la hoja desde la pestaña programador –> insertar –> controles de formulario

Una vez agregado el boton, debemos asignarle la macro para que ejecute el codigo que acabamos de escribir.

Y eso es todo, ahora solo basta con presionar el boton que agregamos y asignamos a la macro, esperar e ir a visualizar a SAP si se creo nuestra OC (Si tienen algun transaction validando campos obligatorios no funcionará al 100% ya que no están incluidos sus campos…ojo con eso.).

Si les aparece el mensaje «OK», quiere decir que se cargó correctamente el documento, de lo contrario aparecerá el mensaje de error correspondiente. Ahora solo basta ir a SAP B1 y revisar el documento.

Y con eso, termina esta publicacion.

Saludos a todos los lectores.