Números de serie y números de lote

Buenas tardes a todos

Hoy les traigo 2 vistas para recopilar información de los movimientos que tienen los números de serie y los números de lote en SAP Business One.

Partiremos con los lotes:

CREATE VIEW BatchNumber_Report
AS

SELECT DISTINCT
    T0.ItemCode AS Cod_Item,
    T0.ItemName AS Nombre_Item, 
    T0.BatchNum AS Lote,
    T0.WhsCode AS Almacen,
    CASE T1.Status
        WHEN 0 THEN 'Liberado'
        WHEN 1 THEN 'Acceso Denegado'
        WHEN 2 THEN 'Bloqueado'
    END AS Estado,
    T2.Quantity AS Cantidad,
    CASE T3.BaseType
        WHEN 13 THEN 'Factura Clientes'
        WHEN 14 THEN 'NC Clientes'
        WHEN 15 THEN 'Entrega'
        WHEN 16 THEN 'Devolucion'
        WHEN 18 THEN 'Factura Proveedor'
        WHEN 19 THEN 'NC Proveedores'
        WHEN 20 THEN 'Entrada mercaderia OP'
        WHEN 21 THEN 'Devolucion mercaderias'
        WHEN 59 THEN 'Entrada mercaderias'
        WHEN 60 THEN 'Salida de mercaderias'
        WHEN 67 THEN 'Traslado stock'
        ELSE CONVERT(NVARCHAR(5),T3.BaseType)
    END AS Documento,
    T3.BaseNum AS NroDocto,
    T4.TransId AS Asiento,
    T3.BaseLinNum AS Linea,
    T3.DocDate AS Fecha,
    T3.WhsCode AS Alm_Docto,
    T3.CardName AS IC,
    CASE T3.Direction
        WHEN 1 THEN T3.Quantity*-1
        ELSE T3.Quantity
    END AS Cant_Docto,
    CASE T3.Direction
        WHEN 1 THEN 'Salida'
        ELSE 'Entrada'
    END AS Sentido   

FROM OIBT T0
INNER JOIN OBTN T1 ON T1.ItemCode=T0.ItemCode AND T1.DistNumber=T0.BatchNum
INNER JOIN OBTQ T2 ON T2.ItemCode=T1.ItemCode AND T2.SysNumber=T1.SysNumber
LEFT JOIN IBT1 T3 ON T3.ItemCode=T0.ItemCode AND T3.BatchNum=T0.BatchNum
LEFT JOIN JDT1 T4 ON T4.TransType=T3.BaseType AND T4.BaseRef=T3.BaseNum AND T4.CreatedBy=T3.BaseEntry

GO

Esta vista, contiene todas las operaciones que tienen que ver con los lotes.
Luego con una select a la vista, podemos obtener el saldo del inventario de los artículos y sus lotes o realizar un reporte de entradas y salida por articulo y lotes en Crystal Reports, va en la creatividad de cada uno.

SELECT DISTINCT
	T0.Cod_Item,
	T0.Nombre_Item,
	T0.Lote,
	T0.Estado,
	T0.Cantidad

FROM BatchNumber_Report T0
WHERE T0.Cantidad>0
UNION ALL
SELECT DISTINCT
	T0.Cod_Item,
	T0.Nombre_Item,
	'Z Total ' + T0.Cod_Item,
	'',
	SUM(T0.Cantidad)

FROM BatchNumber_Report T0
WHERE T0.Cantidad>0
GROUP BY T0.Cod_Item, T0.Nombre_Item, T0.Cantidad
ORDER BY 1,3

Ahora compararemos lo que dice el reporte de auditoria de stock y lo que entrega el resultado de la query:

Ahora haré lo mismo pero con los números de serie, la vista:

CREATE VIEW SerialNumber_Report 
AS

SELECT DISTINCT
    T0.ItemCode AS Cod_Item,
    T0.ItemName AS Nombre_Item, 
    T0.IntrSerial AS Serie,
    T0.WhsCode AS Almacen,
    CASE T0.Status
        WHEN 0 THEN 'Disponible'
        WHEN 1 THEN 'No disponible'
        WHEN 2 THEN 'Imputado'
    END AS Estado,
    T2.Quantity AS Cantidad,
    CASE T3.BaseType
        WHEN 13 THEN 'Factura Clientes'
        WHEN 14 THEN 'NC Clientes'
        WHEN 15 THEN 'Entrega'
        WHEN 16 THEN 'Devolucion'
        WHEN 18 THEN 'Factura Proveedor'
        WHEN 19 THEN 'NC Proveedores'
        WHEN 20 THEN 'Entrada mercaderia OP'
        WHEN 21 THEN 'Devolucion mercaderias'
        WHEN 59 THEN 'Entrada mercaderias'
        WHEN 60 THEN 'Salida de mercaderias'
        WHEN 67 THEN 'Traslado stock'
        ELSE CONVERT(NVARCHAR(5),T3.BaseType)
    END AS Documento,
    T3.BaseNum AS NroDocto,
    T4.TransId AS Asiento,
    T3.BaseLinNum AS Linea,
    T3.DocDate AS Fecha,
    T3.WhsCode AS Alm_Docto,
    T3.CardName AS IC,
    CASE T3.Direction
        WHEN 1 THEN 'Salida'
        ELSE 'Entrada'
    END AS Sentido   

FROM OSRI T0
INNER JOIN OSRN T1 ON T1.ItemCode=T0.ItemCode AND T1.DistNumber=T0.IntrSerial
INNER JOIN OSRQ T2 ON T2.ItemCode=T1.ItemCode AND T2.SysNumber=T1.SysNumber
LEFT JOIN SRI1 T3 ON T3.ItemCode=T0.ItemCode AND T3.SysSerial=T1.SysNumber
LEFT JOIN JDT1 T4 ON T4.TransType=T3.BaseType AND T4.BaseRef=T3.BaseNum AND T4.CreatedBy=T3.BaseEntry

GO

El query:

SELECT DISTINCT
	T0.Cod_Item,
	T0.Nombre_Item,
	T0.Serie,
	T0.Estado,
	T0.Cantidad

FROM SerialNumber_Report T0
WHERE T0.Cantidad>0
UNION ALL
SELECT DISTINCT
	T0.Cod_Item,
	T0.Nombre_Item,
	'Z Total ' + T0.Cod_Item,
	'',
	SUM(T0.Cantidad)

FROM SerialNumber_Report T0
WHERE T0.Cantidad>0
GROUP BY T0.Cod_Item, T0.Nombre_Item, T0.Cantidad
ORDER BY 1,3

Y por ultimo, la comparación

Bueno, eso es todo.
Espero les haya gustado