Actualizar registros en SAP B1 desde excel usando la DI API

He hablado ya en 3 ocaciones sobre como crear registros en SAP B1 usando la DI API desde MS Excel. Pero la DI API no es solo para crear nuevos registros, dependiendo del objeto que estemos usando podemos tambien actualizar, cancelar, eliminar o cerrar (mismas operaciones que valida el transaction).

Para saber que métodos permite un objeto, debemos ir a la documentacion (SDK help) que trae Business One, una vez ahí debemos buscar el objeto para ver que metodos permite.

Personalmente, al inicio, no comprendía bien para que servía el SDK, pero una vez que empece a programar algunas aplicaciones descubrí la gran utilidad e información que nos entrega.

Lo primero que debemos hacer al trabajar con la DI API, es buscar el objeto con el que vamos a trabajar.

En la pestaña index, escribimos «boo» y nos aparecerá de primera opción «BoObjecTypes Enumeration».
La columna «Member» es el nombre único del objeto, la columna «Value» contiene el número de indentificación en la base de datos y la columna «Description» contiene el objeto al cual pertenece.

Para los que leyeron el artculo anterior
Importar ordenes de compra desde excel via DI API

En el codigo está la siguiente sintax:

Dim vDoc As SAPbobsCOM.Documents
        
Set vDoc = oCompany.GetBusinessObject(oPurchaseOrders)

Si volvemos al SDK\BoObjecTypes Enumeration veremos que el documento «oPurchaseOrders» (orden de compra o pedido de compra), pertenece al objeto «Documents» y es por eso que se declara de esa manera. Si en vez de una orden de compra, quisieramos trabajar un pago recibido, habría que cambiar la syntax a la siguiente (siguiendo al SDK):

Dim vDoc As SAPbobsCOM.Payments
        
Set vDoc = oCompany.GetBusinessObject(oIncomingPayments)

Los métodos que tiene un objeto se pueden ver accediendo a él, haciendo clic en el nombre del objeto (de color azul y subrayado) en la lista de objetos del SDK y luego en «members».

Como vemos en la imagen, el objeto «items» tiene los metodos añadir, cancelar, remover, actualizar, es decir que podemos realizar esas acciones desde una aplicacion externa.

Bien, ya hemos hablado mucho de como usar la SDK (objetivo que no era de este post, pero me gusta que aprendan), ahora vamos a hablar del objeto que deseamos trabajar.

Vamos a trabajar con el objeto Items (articulos) y vamos a actualizar un campo «X» masivamente.

Lo primero que tenemos que tener es una planilla con los ItemCode de los articulos en la primera columna de excel hacia abajo

Ahora vamos a colocar el siguiente codigo

Public oCompany As SAPbobsCOM.Company
Public Sub ConnSAP()

        Dim lRetCode, ErrorCode As Long
        Dim ErrorMessage As String
        
        Set oCompany = New SAPbobsCOM.Company
        
        oCompany.DbServerType = SAPbobsCOM.BoDataServerTypes.dst_MSSQL2008
        oCompany.DbUserName = "sa"
        oCompany.DbPassword = "SAP*****"
        oCompany.Server = "sap9"
        oCompany.CompanyDB = "SBO_DemoCL"
        oCompany.UserName = "manager"
        oCompany.Password = "bes****"
        oCompany.UseTrusted = False
        oCompany.Language = ln_Spanish_La
        
        lRetCode = oCompany.Connect()
        If lRetCode <> 0 Then
            MsgBox (oCompany.GetLastErrorDescription())
        Else
            Act_item
        End If
End Sub
Public Sub Act_item()
        
        Dim Retval As Long
        Dim oItem As SAPbobsCOM.Items
        
        Set oItem = oCompany.GetBusinessObject(oItems)
        
        Row = 2
        
        Do While ActiveSheet.Cells(Row, 1) <> ""
            If (oItem.GetByKey(ActiveSheet.Cells(Row, 1)) = True) Then
                oItem.ItemName = ActiveSheet.Cells(Row, 2)
                oItem.ForeignName = ActiveSheet.Cells(Row, 3)
                
                Retval = oItem.Update()
                If Retval <> 0 Then
                    MsgBox (oCompany.GetLastErrorDescription())
                Else
                    ActiveSheet.Cells(Row, 4) = oItem.ItemCode & " actualizado"
                End If
            End If
            
            Row = Row + 1
            
        Loop
            
        MsgBox ("Proceso terminado")
        
        oCompany.Disconnect
End Sub

En este caso, lo primero que debemos decirle a la DI API es que encuentre el producto, para eso utilizamos el método «GetByKey», al cual le debemos pasar el ItemCode (la clave unica del objeto).

Si encuentra el Item devolvera un «true» y en caso de que sea así seteamos el nombre y nombre extranjero (ustedes pueden añadir mas campos si así lo desean) con los valores en las celdas correspondientes e invocamos el metodo «Update» el cual intenta actualizar el item con los nuevos valores seteados.

Por último, agregan un boton y asignan la macro «ConnSAP» para que se ejecute el codigo y esperamos a que termine.

Con eso me despido, espero les sirva.